use "c:\data\mlogit.dta"

generate st1 = 1 - dd2 - dd3
generate st2 = dd2
generate st3 = dd3
generate st = .
replace st = 1 if (st1 == 1)
replace st = 2 if (st2 == 1)
replace st = 3 if (st3 == 1)
list st1 st2 st3 st x1 x2
* As we can see, the data is in the WIDE FORM.

* Tabulate the dependent variable (st)
tabulate st

* Multinomial logit with base outcome alternative 1 (store 1)
mlogit st x1 x2, baseoutcome(1) nolog

* Odds Ratio estimates - Multinomial logit with base outcome alternative 1 (store 1)
mlogit st x1 x2, rr baseoutcome(1) nolog

* Predict probabilities of choice of each store and compare to actual freqs
quietly mlogit st x1 x2, baseoutcome(1)
predict pmlogit1 pmlogit2 pmlogit3, pr
summarize pmlogit* st, separator(3)
list pmlogit* in 1/10

* Create Classification Table and get accuracy rate

egen pred_max = rowmax(pmlogit*)
generate pred_choice = .
forv i=1/3 {
replace pred_choice = `i' if (pred_max == pmlogit`i')
}
local st_label: value label st
label values pred_choice `st_label'
tabulate pred_choice st

* Accuracy rate = (104 + 198 + 98)/1000 = 0.40
* In comparison, the accuracy rate that one would expect from naively classifying
* using the majority class (store = 2) would be 34.4% accuracy on average.
* See the previous tabulation result for the dependent variable - st.
* Thus, the current mlogit classifier is providing a LIFT of 40.00/34.4 = 1.16.